You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
775 lines
32 KiB
775 lines
32 KiB
%% filename: cyrpunc.mf
|
|
%% version: 2.2
|
|
%% date: 1995/01/04
|
|
%%
|
|
%% American Mathematical Society
|
|
%% Technical Support
|
|
%% Publications Technical Group
|
|
%% 201 Charles Street
|
|
%% Providence, RI 02904
|
|
%% USA
|
|
%% tel: (401) 455-4080
|
|
%% (800) 321-4267 (USA and Canada only)
|
|
%% fax: (401) 331-3842
|
|
%% email: tech-support@ams.org
|
|
%%
|
|
%% Copyright 1995 Humanities and Arts Computing Center, University of
|
|
%% Washington.
|
|
%%
|
|
%% Unlimited copying and redistribution of this file are permitted as
|
|
%% long as this file is not modified. Modifications, and distribution
|
|
%% of modified versions, are permitted, but only if the resulting file
|
|
%% is renamed.
|
|
%%
|
|
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
|
|
% cyrpunc punctuation and digits for cyrillic
|
|
|
|
cmchar "Exclamation point";
|
|
beginchar("!",5u#+width_adj#,asc_height#,0);
|
|
italcorr asc_height#*slant-2u#-.5width_adj#+.5dot_size#;
|
|
adjust_fit(0,0);
|
|
pickup tiny.nib; pos3(dot_size,0); pos4(dot_size,90);
|
|
lft x3l=hround(.5w-.5dot_size); bot y4l=0; z3=z4; dot(3,4); % dot
|
|
numeric bot_width;
|
|
bot_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
|
|
pickup fine.nib; pos1(dot_size,0); pos2(bot_width,0);
|
|
x1=x2=x3; bot y2=.25[top y4r,x_height]+1;
|
|
if square_dots: top y1=h;
|
|
filldraw stroke z1e--z2e; % stem
|
|
else: top z0=(x1,h+o); y1+.5dot_size=h+o;
|
|
filldraw z1r...z0...z1l---z2l--z2r---cycle; fi % stem and bulb
|
|
penlabels(0,1,2,3,4); endchar;
|
|
|
|
cmchar "Per cent sign";
|
|
beginchar("%",9u#+max(6u#,2fudge*(hair#+stem#)),
|
|
body_height#,body_height#-asc_height#);
|
|
italcorr if hefty: .4asc_height#*slant-.5u# else: h#*slant-u# fi;
|
|
adjust_fit(0,0); pickup fine.nib;
|
|
numeric left_curve,right_curve;
|
|
left_curve=hround 5/6[fudged.hair,fudged.stem];
|
|
right_curve=max(fine.breadth,hround(fudged.hair if hefty:-2stem_corr fi));
|
|
pos1(vair,90); pos2(left_curve,180); pos3(vair,270); pos4(right_curve,360);
|
|
top y1r=h; lft x2r=hround u; rt x4r=hround(.5w-1.5u);
|
|
bot y3r=floor(if monospace: .7 else: .5 fi\\ asc_height);
|
|
x1=x3=.5[x2,x4]; y2=y4=.5[y1,y3];
|
|
filldraw stroke pulled_super_arc.e(1,2)(superpull)
|
|
& pulled_super_arc.e(2,3)(superpull); % left half of upper bowl
|
|
filldraw stroke super_arc.e(3,4) & super_arc.e(4,1); % right half of upper bowl
|
|
pos5(vair,90); pos6(left_curve,180); pos7(vair,270); pos8(right_curve,360);
|
|
bot y7r=-d; rt x8r=hround(w-u); lft x6r=hround(.5w+1.5u);
|
|
top y5r=vround(if monospace: .3 else: .5 fi\\ asc_height);
|
|
x5=x7=.5[x6,x8]; y6=y8=.5[y5,y7];
|
|
filldraw stroke pulled_super_arc.e(5,6)(superpull)
|
|
& pulled_super_arc.e(6,7)(superpull); % left half of lower bowl
|
|
filldraw stroke super_arc.e(7,8) & super_arc.e(8,5); % right half of lower bowl
|
|
pickup rule.nib; top y9=h; bot y10=-d;
|
|
if hefty: x9=good.x(x5-eps); x10=good.x(x1+eps);
|
|
draw z9--z10; % diagonal
|
|
else: rt x9=hround(w-2.5u); lft x10=hround 2.5u; draw z9--z10; % diagonal
|
|
pickup fine.nib; pos9(rule_thickness,angle(z9-z10)+90);
|
|
pos11(vair,angle(z1r-z4r)-90); pos12(vair,angle(z9-z10)+90);
|
|
path p; p=super_arc.r(1,4); z11r=point 2/3 of p; z12r=z9r;
|
|
filldraw stroke z11e{direction 2/3 of p}...{z9-z10}z12e; fi % link
|
|
penlabels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
|
|
|
|
cmchar "Apostrophe";
|
|
beginchar("'",5u#,asc_height#,0);
|
|
italcorr asc_height#*slant+.5dot_size#-2u#;
|
|
adjust_fit(0,0);
|
|
x1-.5dot_size=hround(.5w-.5dot_size); y1+.5dot_size=h;
|
|
if monospace: comma(1,a,dot_size,.28u,vround 1.5comma_depth); % large comma
|
|
else: comma(1,a,dot_size,.25u,comma_depth); fi % comma with increased jut
|
|
penlabels(1); endchar;
|
|
|
|
cmchar "Left parenthesis";
|
|
beginchar("(",7u# if monospace: -u# fi,body_height#,paren_depth#);
|
|
italcorr body_height#*slant-.5u#;
|
|
adjust_fit(0,0); pickup fine.nib;
|
|
pos1(vair,0); pos2(.75[hair,stem],0); pos3(vair,0);
|
|
rt x1r=rt x3r=hround(w-u); lft x2l=hround(x1-4u if monospace: +4/3u fi);
|
|
top y1=h; y2=.5[y1,y3]=math_axis;
|
|
filldraw stroke z1e{3(x2e-x1e),y2-y1}...z2e
|
|
...{3(x3e-x2e),y3-y2}z3e; % arc
|
|
penlabels(1,2,3); endchar;
|
|
|
|
cmchar "Right parenthesis";
|
|
beginchar(")",7u# if monospace: -u# fi,body_height#,paren_depth#);
|
|
italcorr math_axis#*slant-.5u#;
|
|
adjust_fit(0,0); pickup fine.nib;
|
|
pos1(vair,0); pos2(.75[hair,stem],0); pos3(vair,0);
|
|
lft x1l=lft x3l=hround u; rt x2r=hround(x1+4u if monospace: -4/3u fi);
|
|
top y1=h; y2=.5[y1,y3]=math_axis;
|
|
filldraw stroke z1e{3(x2e-x1e),y2-y1}...z2e
|
|
...{3(x3e-x2e),y3-y2}z3e; % arc
|
|
penlabels(1,2,3); endchar;
|
|
|
|
cmchar "Asterisk";
|
|
beginchar("*",9u#,
|
|
if low_asterisk:math_axis#+.5x_height# else: body_height# fi,0);
|
|
italcorr h#*slant-.75u#;
|
|
adjust_fit(0,0);
|
|
numeric ast_flare; ast_flare=hround .7[thin_join,stem];
|
|
x0=.5w; y0=h-.5x_height;
|
|
for d=-150 step 60 until 150: z[d]=z0+.5dir d xscaled 7.5u yscaled x_height;
|
|
numeric theta; theta=angle(z[d]-z0);
|
|
fill z0+.5(0,-thin_join)rotated theta
|
|
---z[d]+.5(-ast_flare,-ast_flare)rotated theta
|
|
..z[d]..z[d]+.5(-ast_flare,ast_flare)rotated theta
|
|
---z0+.5(0,thin_join)rotated theta--cycle; endfor % diagonal at angle |d|
|
|
labels(0,[-150],[-90],[-30],30,90,150); endchar;
|
|
|
|
cmchar "Comma";
|
|
numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
|
|
define_whole_blacker_pixels(dot_diam);
|
|
beginchar(",",5u#,dot_diam#,comma_depth#);
|
|
adjust_fit(0,0);
|
|
x1-.5dot_diam=hround(.5w-.5dot_diam); y1-.5dot_diam=0;
|
|
comma(1,a,dot_diam,.2u,comma_depth); % dot and tail
|
|
penlabels(1); endchar;
|
|
|
|
cmchar "Hyphen";
|
|
beginchar("-",6u#,x_height#,0);
|
|
italcorr .5x_height#*slant-.5u#;
|
|
adjust_fit(0,0);
|
|
numeric thickness; thickness=if hefty:bar else:.75[hair,stem] fi;
|
|
pickup crisp.nib; pos1(thickness,90); pos2(thickness,90);
|
|
top y1r=top y2r=vround(.5h+.5thickness); rt x2=hround(w-u)+eps;
|
|
if monospace: x2=w-x1 else: lft x1=hround .2u-eps fi;
|
|
filldraw stroke z1e--z2e; % bar
|
|
penlabels(1,2); endchar;
|
|
|
|
cmchar "Period";
|
|
numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
|
|
define_whole_blacker_pixels(dot_diam);
|
|
beginchar(".",5u#,dot_diam#,0);
|
|
adjust_fit(0,0); pickup fine.nib;
|
|
pos1(dot_diam,0); pos2(dot_diam,90);
|
|
lft x1l=hround(.5w-.5dot_diam); bot y2l=0; z1=z2; dot(1,2); % dot
|
|
penlabels(1,2); endchar;
|
|
|
|
cmchar "Virgule (slash)";
|
|
beginchar("/",9u#,body_height#,paren_depth#);
|
|
italcorr body_height#*slant-.5u#;
|
|
adjust_fit(0,0); pickup rule.nib;
|
|
rt x1=hround(w-u)+eps; top y1=h+eps;
|
|
lft x2=hround u-eps; bot y2=-d-eps;
|
|
draw z1--z2; % diagonal
|
|
penlabels(1,2); endchar;
|
|
|
|
cmchar "Colon";
|
|
numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
|
|
define_whole_blacker_pixels(dot_diam);
|
|
beginchar(":",5u#,x_height#,0);
|
|
italcorr x_height#*slant+.5dot_diam#-2u#;
|
|
adjust_fit(0,0); pickup fine.nib;
|
|
pos1(dot_diam,0); pos2(dot_diam,90);
|
|
lft x1l=hround(.5w-.5dot_diam); top y2r=h; z1=z2; dot(1,2); % upper dot
|
|
pos3(dot_diam,0); pos4(dot_diam,90);
|
|
x3=x1; bot y4l=0; z3=z4; dot(3,4); % lower dot
|
|
penlabels(1,2,3,4); endchar;
|
|
|
|
cmchar "Semicolon";
|
|
numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
|
|
define_whole_blacker_pixels(dot_diam);
|
|
beginchar(";",5u#,x_height#,comma_depth#);
|
|
italcorr x_height#*slant+.5dot_diam#-2u#;
|
|
adjust_fit(0,0); pickup fine.nib;
|
|
pos1(dot_diam,0); pos2(dot_diam,90);
|
|
lft x1l=hround(.5w-.5dot_diam); top y2r=h; z1=z2; dot(1,2); % upper dot
|
|
x3-.5dot_diam=hround(.5w-.5dot_diam); y3-.5dot_diam=0;
|
|
comma(3,a,dot_diam,.05u,comma_depth); % lower dot and tail
|
|
penlabels(1,2,3); endchar;
|
|
|
|
cmchar "Question mark";
|
|
beginchar("?",8.5u#,asc_height#,0);
|
|
italcorr .8asc_height#*slant;
|
|
adjust_fit(0,0);
|
|
pickup tiny.nib; pos7(dot_size,0); pos8(dot_size,90);
|
|
lft x7l=hround(.5w-.25u-.5dot_size); bot y8l=0; z7=z8; dot(7,8); % dot
|
|
numeric bot_width;
|
|
bot_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
|
|
pickup fine.nib; pos2(vair,90); pos3(curve,0);
|
|
pos4(vair,-90); pos5(bot_width,0); pos6(bot_width,0);
|
|
x2=x4=x5=x6=x7; rt x3r=hround(w-u); bot y6=1+.25[top y8r,x_height];
|
|
top y2r=h+oo; y3=.75[y6,y2]; y4=.5[y6,y2]; y5=.1[y6,y2];
|
|
{{interim superness:=more_super;
|
|
filldraw stroke pulled_super_arc.e(2,3)(superpull)
|
|
& subpath (0,1) of super_arc.e(3,4) .. z5e---z6e\\}}; % arc and stem
|
|
if serifs: pos1(hair,180); pos0(flare,180);
|
|
lft x1r=hround u; y1=y3; bulb(2,1,0); % bulb
|
|
else: pos1(Vround 5/7[vair,flare],110);
|
|
lft x1r=hround u; top y1r=vround .9[y6,top y2r];
|
|
filldraw stroke term.e(2,1,left,1,4); fi % terminal
|
|
penlabels(0,1,2,3,4,5,6,7,8); endchar;
|
|
|
|
cmchar "Left bracket";
|
|
numeric wd#; wd#=max(5u#,4.5u#+.5if hefty:stem# else:rule_thickness# fi);
|
|
beginchar("[",wd#,body_height#,paren_depth#);
|
|
italcorr body_height#*slant;
|
|
adjust_fit(0,0);
|
|
numeric top_thickness,side_thickness;
|
|
if hefty: top_thickness=vair;
|
|
side_thickness=max(crisp.breadth,stem-2stem_corr);
|
|
else: top_thickness=side_thickness=rule_thickness; fi;
|
|
pickup crisp.nib; pos1(side_thickness,0); pos2(side_thickness,0);
|
|
top y1=h; bot y2=-d; lft x1l=lft x2l=hround(2.5u-.5side_thickness)-1-eps;
|
|
filldraw stroke z1e--z2e; % stem
|
|
pos3(top_thickness,90); pos4(top_thickness,90);
|
|
pos5(top_thickness,90); pos6(top_thickness,90);
|
|
x3=x5=x1l; rt x4=rt x6=ceiling(w-.4u)+eps; y3r=y4r=y1; y5l=y6l=y2;
|
|
filldraw stroke z3e--z4e; % upper bar
|
|
filldraw stroke z5e--z6e; % lower bar
|
|
penlabels(1,2,3,4,5,6); endchar;
|
|
|
|
cmchar "Right bracket";
|
|
numeric wd#; wd#=max(5u#,4.5u#+.5if hefty:stem# else:rule_thickness# fi);
|
|
beginchar("]",wd#,body_height#,paren_depth#);
|
|
italcorr body_height#*slant-2u#+.5if hefty:stem# else:rule_thickness# fi;
|
|
adjust_fit(0,0);
|
|
numeric top_thickness,side_thickness;
|
|
if hefty: top_thickness=vair;
|
|
side_thickness=max(crisp.breadth,stem-2stem_corr);
|
|
else: top_thickness=side_thickness=rule_thickness; fi;
|
|
pickup crisp.nib; pos1(side_thickness,0); pos2(side_thickness,0);
|
|
top y1=h; bot y2=-d; rt x1r=rt x2r=hround(w-2.5u+.5side_thickness)+1+eps;
|
|
filldraw stroke z1e--z2e; % stem
|
|
pos3(top_thickness,90); pos4(top_thickness,90);
|
|
pos5(top_thickness,90); pos6(top_thickness,90);
|
|
x3=x5=x1r; lft x4=lft x6=floor .4u-eps; y3r=y4r=y1; y5l=y6l=y2;
|
|
filldraw stroke z3e--z4e; % upper bar
|
|
filldraw stroke z5e--z6e; % lower bar
|
|
penlabels(1,2,3,4,5,6); endchar;
|
|
|
|
cmchar "Reverse apostrophe";
|
|
beginchar("`",5u#,asc_height#,0);
|
|
italcorr asc_height#*slant+.5dot_size#-2u#;
|
|
adjust_fit(0,0);
|
|
x1-.5dot_size=hround(.5w-.5dot_size); y1+.5dot_size=h-comma_depth;
|
|
if monospace: ammoc(1,a,dot_size,.28u,vround 1.5comma_depth); % large ammoc
|
|
else: ammoc(1,a,dot_size,.25u,comma_depth); fi % normal ammoc
|
|
penlabels(1); endchar;
|
|
|
|
cmchar "The numeral 0";
|
|
beginchar("0",9u#,fig_height#,0);
|
|
italcorr fig_height#*slant-.5u#;
|
|
adjust_fit(0,0);
|
|
penpos1(vair,90); penpos3(vair,-90); penpos2(curve,180); penpos4(curve,0);
|
|
if not monospace: interim superness:=sqrt(more_super*hein_super); fi
|
|
x2r=hround max(.7u,1.45u-.5curve); x4r=w-x2r; x1=x3=.5w;
|
|
y1r=h+o; y3r=-o; y2=y4=.5h-vair_corr; y2l:=y4l:=.52h;
|
|
penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
|
|
& pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle; % bowl
|
|
penlabels(1,2,3,4); endchar;
|
|
|
|
cmchar "The numeral 1";
|
|
beginchar("1",9u#,fig_height#,0);
|
|
italcorr fig_height#*slant-.5u#;
|
|
adjust_fit(0,0);
|
|
numeric light_stem; light_stem=hround .4[stem',cap_stem'];
|
|
pickup tiny.nib;
|
|
pos1(light_stem,0); pos2(light_stem,0);
|
|
lft x1l=lft x2l=hround(.5(w+.5u)-.5cap_stem'); top y1=h+o; bot y2=0;
|
|
filldraw stroke z1e--z2e; % stem
|
|
if not serifs: save slab; slab=bar; fi
|
|
dish_serif(2,1,a,1/3,min(2.25u,lft x2l-1.5u),
|
|
b,1/3,min(2.25u,w-1.25u-rt x2r)); % serif
|
|
pickup crisp.nib; pos3(slab,-90); pos4(bar,-90);
|
|
top y3l=h+o; top y4l=if monospace: .8 else: .9 fi\\ h+o;
|
|
lft x4=max(1.25u,tiny.lft x1l-2.35u);
|
|
tiny.rt x1r=lft x3+.25[tiny,hair];
|
|
erase fill z3l{x4l-x3l,3(y4l-y3l)}...z4l{left}
|
|
--(x4l,h+o+1)--(x3l,h+o+1)--cycle; % erase excess at top
|
|
filldraw stroke z3e{x4e-x3e,3(y4e-y3e)}..z4e{left}; % point
|
|
penlabels(1,2,3,4); endchar;
|
|
|
|
cmchar "The numeral 2";
|
|
beginchar("2",9u#,fig_height#,0);
|
|
italcorr fig_height#*slant-.5u#;
|
|
adjust_fit(0,0);
|
|
numeric arm_thickness, hair_vair; hair_vair=.25[vair,hair];
|
|
arm_thickness=Vround(if hefty:slab+2stem_corr else:.4[stem,cap_stem] fi);
|
|
pickup crisp.nib; pos7(arm_thickness,-90); pos8(hair,0);
|
|
bot y7r=0; lft x7=hround .9u; rt x8r=hround(w-.9u); y8=good.y(y7l+beak/2)+eps;
|
|
arm(7,8,a,.3beak_darkness,beak_jut); % arm and beak
|
|
pickup fine.nib; pos2(slab,90); pos3(.4[curve,cap_curve],0);
|
|
top y2r=h+o; x2=.5(w-.5u); rt x3r=hround(w-.9u); y3+.5vair=.75h;
|
|
if serifs: numeric bulb_diam; bulb_diam=hround(flare+2/3(cap_stem-stem));
|
|
pos0(bulb_diam,180); pos1(cap_hair,180);
|
|
lft x1r=hround .9u; y1-.5bulb_diam=2/3h;
|
|
(x,y2l)=whatever[z1l,z2r]; x2l:=x; bulb(2,1,0); % bulb and arc
|
|
else: x2l:=x2l-.25u; pos1(flare,angle(-9u,h));
|
|
lft x1r=hround .75u; bot y1l=vround .7h; y1r:=good.y y1r+eps; x1l:=good.x x1l;
|
|
filldraw stroke term.e(2,1,left,.9,4); fi % terminal and arc
|
|
pos4(.25[hair_vair,cap_stem],0);
|
|
pos5(hair_vair,0); pos6(hair_vair,0);
|
|
y5=arm_thickness; y4=.3[y5,y3]; top y6=min(y5,slab,top y7l);
|
|
lft x6l=crisp.lft x7; z4l=whatever[z6l,(x3l,bot .58h)]; z5l=whatever[z6l,z4l];
|
|
erase fill z4l--z6l--lft z6l--(lft x6l,y4l)--cycle; % erase excess at left
|
|
filldraw stroke z2e{right}..tension atleast .9 and atleast 1
|
|
..z3e{down}.. z4e---z5e--z6e; % stroke
|
|
penlabels(0,1,2,3,4,5,6,7,8); endchar;
|
|
|
|
cmchar "The numeral 3";
|
|
beginchar("3",9u#,fig_height#,0);
|
|
italcorr fig_height#*slant-.5u#;
|
|
adjust_fit(0,0);
|
|
numeric top_thickness,mid_thickness,bot_thickness;
|
|
top_thickness=max(fine.breadth,vround(slab-2vair_corr));
|
|
mid_thickness=max(fine.breadth,vround 2/3vair);
|
|
bot_thickness=max(fine.breadth,vround(slab-vair_corr));
|
|
pickup fine.nib; pos2(top_thickness,90); top y2r=h+o;
|
|
pos3(max(fine.breadth,.6[curve,cap_curve]-stem_corr),0);
|
|
rt x3r=hround(w-1.25u);
|
|
pos4(vair,-90); pos5(vair,-90);
|
|
pos6(mid_thickness,90); x2=x6=x8=.5[1.5u,x7];
|
|
pos7(cap_curve,0); rt x7r=hround(w-.75u); lft x5=min(hround 3u,lft x6)-eps;
|
|
pos8(bot_thickness,-90); bot y8r=-o;
|
|
y3=.6[top y4l,bot y2l]; y7=.5[bot y6l,top y8l];
|
|
top y5l=vround(.54h+.5vair); y5r=y6l;
|
|
x4=1/3[x5,x3l]; z4=z5+whatever*(150u,h);
|
|
filldraw stroke pulled_super_arc.e(2,3)(.5superpull)
|
|
& z3e{down}...z4e---z5e; % upper bowl
|
|
filldraw z5r--z6l--z6r--z5l---cycle; % middle tip
|
|
filldraw stroke pulled_super_arc.e(6,7)(.5superpull)
|
|
& pulled_super_arc.e(7,8)(.5superpull); % lower bowl
|
|
if serifs: numeric bulb_diam[];
|
|
bulb_diam1=flare+.5(cap_stem-stem); bulb_diam2=flare+cap_stem-stem;
|
|
pos0(bulb_diam1,180); pos1(hair,180);
|
|
lft x0r=hround 1.25u; y0=min(.9h-.5bulb_diam1,.75h+.5bulb_diam1);
|
|
bulb(2,1,0); % upper bulb
|
|
pos10(bulb_diam2,-180); pos9(cap_hair,-180);
|
|
lft x10r=hround .75u; y10=max(.1h+.5bulb_diam2,.3h-.5bulb_diam2);
|
|
bulb(8,9,10); % lower bulb
|
|
else: pos1(.5[vair,flare],angle(-8u,h));
|
|
lft x1r=hround u; bot y1l=vround .75h+o;
|
|
y1r:=good.y y1r+eps; x1l:=good.x x1l;
|
|
pos9(bot_thickness,angle(-2u,-h));
|
|
lft x9r=hround .75u; top y9l=vround .25h-o;
|
|
y9r:=good.y y9r-eps; x9l:=good.x x9l;
|
|
filldraw stroke term.e(2,1,left,1,4); % upper terminal
|
|
filldraw stroke term.e(8,9,left,1,4); fi % lower terminal
|
|
penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
|
|
|
|
cmchar "The numeral 4";
|
|
beginchar("4",9u#,fig_height#,0);
|
|
italcorr fig_height#*slant-.5u#;
|
|
adjust_fit(0,0);
|
|
numeric light_stem, light_stem', diag_stem, alpha, cut; cut=.75notch_cut;
|
|
light_stem=hround .4[fudged.stem,fudged.cap_stem];
|
|
light_stem'=hround max(tiny.breadth,light_stem-2stem_corr);
|
|
diag_stem=max(tiny.breadth,.4[vair,fudged.hair]);
|
|
pickup crisp.nib; pos5(cap_bar,90); pos6(cap_bar,90);
|
|
lft x5=hround .5u; rt x6=hround(w-.5u);
|
|
top y5r=vround(if serifs: 5/18[slab,h-light_stem]+1
|
|
else:.35(h-light_stem) fi+.5cap_bar);
|
|
z4l=top lft z5r; y2=y2'=y5=y6; x1r=x2r=hround(w-3u+.5light_stem);
|
|
penpos1(light_stem',0); penpos2(light_stem',0); y1=y3=h+apex_o+apex_oo;
|
|
x3r+apex_corr=x1r; alpha=diag_ratio(1,diag_stem,y3-y4l,x3r-x4l);
|
|
penpos3(alpha*diag_stem,0); penpos4(alpha*diag_stem,0);
|
|
x0=x1l; z0=whatever[z3r,z4r];
|
|
x5'=x5; z5''=z5'+penoffset z4-z3 of currentpen=whatever[z4l,z3l];
|
|
fill diag_end(2r,1r,1,.5,3l,4l)---z5''...lft z5'
|
|
---lft z5l -- (x4r,y5l) -- z4r
|
|
if y0<h-cut:{z3r-z4r}...{up}(x1l-1,h-cut)
|
|
--(x1l,h-cut) else: -- z0 fi
|
|
--z2l--z2r--cycle; % diagonal and upper stem
|
|
filldraw stroke z5e--z6e; % bar
|
|
pickup tiny.nib; pos7(light_stem,0); rt x7r=x1r; bot y7=0;
|
|
pos2'(light_stem,0); x2'=x7;
|
|
filldraw stroke z2'e--z7e; % lower stem
|
|
if serifs: dish_serif(7,2',a,1/3,1.75u,
|
|
b,1/3,min(1.75u,w-.5u-rt x7r)); fi % serif
|
|
penlabels(0,1,2,3,4,5,6,7); endchar;
|
|
|
|
cmchar "The numeral 5";
|
|
beginchar("5",9u#,fig_height#,0);
|
|
italcorr fig_height#*slant-.5u#;
|
|
adjust_fit(0,0);
|
|
numeric bot_thickness,light_hair;
|
|
bot_thickness=max(fine.breadth,vround(slab-vair_corr));
|
|
light_hair=hround(cap_hair if hefty: -\\2stem_corr fi);
|
|
pickup tiny.nib; pos5(vair,180); pos6(vair,90);
|
|
bot y5=vround(.53h-vair); top y6r=max(vround .61803h+o,top y6r+y5+eps-y6l);
|
|
pos3(light_hair,0); pos4(light_hair,0);
|
|
lft x3l=max(1.35u,2.1u-.5light_hair); x3=x4=x5; y4=y5;
|
|
top y3=h if not hefty: +\\o fi;
|
|
filldraw stroke z3e--z4e; % thin stem
|
|
penpos7(cap_stem-fine,0); penpos8(bot_thickness-fine,-90);
|
|
fine.rt x7r=hround(w-.9u); x8=.5[u,x7]; x6=.5[x5,x7];
|
|
erase fill z5--bot z5--(x6,bot y5)--z6{left}
|
|
..tension .9 and 1..{x5-x6,3(y5-y6)}cycle; % erase excess in middle
|
|
filldraw stroke z6e{left}..tension .9 and 1..{x5-x6,3(y5-y6)}z5e; % link
|
|
pickup fine.nib; pos6'(vair,90); z6'=z6;
|
|
y7=.5[y6,y8]; bot y8r=-o;
|
|
filldraw stroke pulled_arc.e(6',7) & pulled_arc.e(7,8); % bowl
|
|
if serifs: pos9(hair,-180); y9=.5y5; lft x9r=hround .9u;
|
|
pos10(flare+1/3(cap_stem-stem),-180); bulb(8,9,10); % bulb
|
|
else: pos9(3/7[bot_thickness,flare],angle(-7u,-h));
|
|
lft x9r=hround(tiny.lft x3l-.75u); bot y9r=vround .15h-o;
|
|
x9l:=good.x x9l; y9l:=good.y y9l;
|
|
filldraw stroke term.e(8,9,left,1,4); fi % terminal
|
|
if hefty: pickup crisp.nib; pos1(slab,90); pos2(hair,0);
|
|
top y1r=h; x1=x4; rt x2r=hround(w-1.5u); y2=y1l-eps;
|
|
arm(1,2,a,0,0); % arm
|
|
else: numeric flag_breadth; flag_breadth=7/8[vair,cap_curve];
|
|
pos1(flag_breadth,90); pos2(flag_breadth,60);
|
|
pos0(vair,90); top y1r=tiny.top y3; top y2r=vround .95h+o; y0r=y1r;
|
|
lft x1=tiny.lft x3l; x2r=.5[x1,x0]; rt x0=hround(w-1.6u);
|
|
erase fill top z1r--z1r...{right}z2r
|
|
--(x2r,top y1r)--cycle; % erase excess at top
|
|
filldraw stroke z1e...{right}z2e...z0e; fi % flag
|
|
penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
|
|
|
|
cmchar "The numeral 6";
|
|
beginchar("6",9u#,fig_height#,0);
|
|
italcorr fig_height#*slant-.5u#;
|
|
adjust_fit(0,0);
|
|
numeric top_thickness,bot_thickness,side_thickness,pull;
|
|
top_thickness=max(fine.breadth,vround(slab-2vair_corr));
|
|
bot_thickness=max(fine.breadth,vround(slab-vair_corr));
|
|
side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
|
|
pull=min(.25,1.5superpull);
|
|
pickup fine.nib; pos2(top_thickness,-270);
|
|
pos3(side_thickness,-180); pos4(bot_thickness,-90);
|
|
pos5(side_thickness,0); pos6(vair,90);
|
|
lft x3r=w-rt x5r=hround max(.75u,1.5u-.5side_thickness);
|
|
x4=x6-.1u=x2-u=.5w;
|
|
top y2r=h+o; y3=.5[y2,y4]; bot y4r=-o;
|
|
y5=.5[y4,y6]; top y6=vround 5/8h+o;
|
|
path p; p=pulled_super_arc.l(3,4)(pull);
|
|
numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
|
|
pos7(thin_join,180); z7l=point t of p;
|
|
(x,y6r)=whatever[z7l,z6l]; x6r:=min(x,.5[x5r,x6]);
|
|
filldraw stroke pulled_super_arc.e(2,3)(pull)
|
|
& {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
|
|
& {{less_tense; pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
|
|
& z6e{left}...{direction t of p}z7e; % arc and bowl
|
|
if serifs: pos1(hair,-360); pos0(flare,-360);
|
|
rt x0r=max(rt x2+eps,hround(w-1.2u));
|
|
y0=vround min(.9h-.5flare,.85h+.5flare)+o;
|
|
{{less_tense; bulb(2,1,0)}}; % arc and bulb
|
|
else: pos1(vround .1[top_thickness,flare],90);
|
|
top y1r=vround .97h+o; rt x1=hround(x5-.5);
|
|
filldraw stroke term.e(2,1,right,.9,4); fi % terminal
|
|
penlabels(0,1,2,3,4,5,6,7); endchar;
|
|
|
|
cmchar "The numeral 7";
|
|
beginchar("7",9u#,fig_height#,0);
|
|
italcorr fig_height#*slant-.5u#;
|
|
adjust_fit(0,0);
|
|
numeric arm_thickness, bot_width, top_shift, top_hair;
|
|
if hefty: arm_thickness=Vround(slab+2stem_corr); top_shift=0;
|
|
bot_width=hround .51[curve,cap_curve]; top_hair=.4[thin_join,bot_width];
|
|
else: arm_thickness=Vround .4[stem,cap_stem]; top_shift=.5u;
|
|
bot_width=flare; top_hair=cap_hair; fi
|
|
if top_hair<tiny.breadth: top_hair:=tiny.breadth; fi
|
|
pickup crisp.nib; pos2(arm_thickness,90); pos1(hair,180);
|
|
top y2r=h; rt x2=hround(w-.75u+top_shift);
|
|
lft x1r=hround(.75u+.5top_shift); y1=good.y(y2l-beak/2)-eps;
|
|
arm(2,1,a,.3beak_darkness,-beak_jut); % arm and beak
|
|
pos3(hair,180); y3=good.y(y2r+beak/6)+eps; z3r=whatever[z1r,z.a0];
|
|
penpos2'(eps,-90); z2'=z2r;
|
|
arm(2',3,b,beak_darkness,x3r-x.a0); % upward extension of beak
|
|
pickup tiny.nib; pos4(top_hair,0); pos6(bot_width,0);
|
|
bot y4=max(h-arm_thickness,h-slab,bot y2l); rt x4r=crisp.rt x2;
|
|
lft x6l=hround(3.5u+top_shift-.5bot_width);
|
|
if serifs: y6-.5bot_width=-o; filldraw z6l{down}..{up}z6r--cycle; % bulb
|
|
else: bot y6=-oo; fi
|
|
if hefty: erase fill rt z4r--z4r...{down}z6r
|
|
--(rt x4r,y6)--cycle; % erase excess at top
|
|
filldraw stroke z4e...{down}z6e; % stroke
|
|
else: pos5(top_hair,0); y5=2/3h; z5=whatever[z4,(.75u,y6)];
|
|
erase fill rt z4r--z4r--z5r--(rt x4r,y5)--cycle; % erase excess at top
|
|
filldraw stroke z4e---z5e...{down}z6e; fi % stroke
|
|
penlabels(1,2,3,4,5,6); endchar;
|
|
|
|
cmchar "The numeral 8";
|
|
beginchar("8",9u#,fig_height#,0);
|
|
italcorr fig_height#*slant-.5u#;
|
|
adjust_fit(0,0);
|
|
numeric top_thickness,mid_thickness,bot_thickness,upper_side,lower_side,theta;
|
|
top_thickness=max(fine.breadth,vround(slab-2vair_corr));
|
|
bot_thickness=max(fine.breadth,vround(slab-vair_corr));
|
|
x0=.5w; y0=.54h;
|
|
if hefty: mid_thickness=vround 2/3vair; upper_side=hround(stem-3stem_corr);
|
|
lower_side=hround min(.5[curve,cap_curve]-stem_corr,upper_side+.25u);
|
|
penpos1(top_thickness,90); penpos2(upper_side,180);
|
|
penpos3(mid_thickness,270); penpos8(upper_side,360);
|
|
penpos4(mid_thickness,90); penpos7(lower_side,180);
|
|
penpos6(bot_thickness,270); penpos5(lower_side,360);
|
|
penpos0(vair,90); z3l=z0r; z4l=z0l;
|
|
x1=x6=.5w; x2r=w-x8r=hround u; x7r=w-x5r=hround .75u;
|
|
top y1r=h+o; bot y6r=-o; y2=y8=.5[y1l,y3l]; y7=y5=.5[y4l,y6l];
|
|
filldraw stroke pulled_arc.e(1,2)
|
|
& pulled_arc.e(2,3); % left half of upper bowl
|
|
filldraw stroke pulled_arc.e(4,5)
|
|
& pulled_arc.e(5,6); % right half of lower bowl
|
|
filldraw stroke pulled_arc.e(6,7)
|
|
& pulled_arc.e(7,4); % left half of lower bowl
|
|
filldraw stroke pulled_arc.e(3,8)
|
|
& pulled_arc.e(8,1); % right half of upper bowl
|
|
else: pickup fine.nib; theta=90-angle(18u,h); slope:=-h/18u;
|
|
upper_side=max(fine.breadth,hround(.5[hair,stem]-stem_corr));
|
|
lower_side=hround(.5[hair,stem]+stem_corr);
|
|
pos1(top_thickness,-90); pos6(bot_thickness,-90);
|
|
x1=x6=.5w; top y1l=h+o; bot y6r=-o; pos0(cap_stem,theta);
|
|
lft x2l=w-rt x8l=hround 1.25u; lft x7r=w-rt x5r=hround .75u;
|
|
x2r-x2l=upper_side-fine; x5r-x5l=lower_side-fine;
|
|
ellipse_set(1l,2l,3l,0l); ellipse_set(1r,2r,3r,0r);
|
|
ellipse_set(6l,5l,4l,0l); ellipse_set(6r,5r,4r,0r);
|
|
numeric tau; tau=max(.8,.20710678/(superness-.5));
|
|
filldraw stroke z1e{left}..tension atleast tau..z2e{down}
|
|
..z3e---z4e..z5e{down}..tension atleast tau..z6e{left}; % S stroke
|
|
pos7(lower_side,180); pos8(upper_side,180);
|
|
y7=.5[y5l,y5r]; y8=.5[y2l,y2r]; pos9(vair,90); z9=z0;
|
|
filldraw stroke z1e{right}..tension atleast tau..z8e{down}
|
|
..tension atleast tau and atleast 1..{-18u,-.618h}z9e; % upper right stroke
|
|
filldraw stroke z6e{left}..tension atleast tau..z7e{up}
|
|
..tension atleast tau and atleast 1..{18u,.5h}z9e; fi % lower left stroke
|
|
penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
|
|
|
|
cmchar "The numeral 9";
|
|
beginchar("9",9u#,fig_height#,0);
|
|
italcorr fig_height#*slant-.5u#;
|
|
adjust_fit(0,0);
|
|
numeric top_thickness,bot_thickness,side_thickness,pull;
|
|
top_thickness=max(fine.breadth,vround(slab-2vair_corr));
|
|
bot_thickness=max(fine.breadth,vround(slab-vair_corr));
|
|
side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
|
|
pull=min(.25,1.5superpull);
|
|
pickup fine.nib; pos2(bot_thickness,-90);
|
|
pos3(side_thickness,0); pos4(top_thickness,90);
|
|
pos5(side_thickness,180); pos6(vair,270);
|
|
w-rt x3r=lft x5r=hround max(.75u,1.5u-.5side_thickness);
|
|
x4-.1u=x6+.1u=x2+.75u=.5w;
|
|
bot y2r=-o; y3=.5[y2,y4]; top y4r=h+o;
|
|
y5=.5[y4,y6]; bot y6=vround 3/8h-o;
|
|
path p; p=pulled_super_arc.l(3,4)(pull);
|
|
numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
|
|
pos7(thin_join,360); z7l=point t of p;
|
|
(x,y6r)=whatever[z7l,z6l]; x6r:=max(x,.5[x5r,x6]);
|
|
filldraw stroke pulled_super_arc.e(2,3)(pull)
|
|
& {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
|
|
& {{less_tense; pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
|
|
& z6e{right}...{direction t of p}z7e; % arc and bowl
|
|
if serifs: pos1(hair,-180); pos0(flare,-180);
|
|
lft x0r=min(lft x2-eps,hround 1.2u);
|
|
y0=vround max(.1h+.5flare,.15h-.5flare)-o;
|
|
{{less_tense; bulb(2,1,0)}}; % arc and bulb
|
|
else: pos1(.1[bot_thickness,flare],-120);
|
|
bot y1r=vround .07h-o; lft x1r=hround 1.3u;
|
|
filldraw stroke term.e(2,1,left,.9,4); fi % terminal
|
|
penlabels(0,1,2,3,4,5,6,7); endchar;
|
|
|
|
cmchar "Umlaut (double dot) accent";
|
|
numeric dot_diam#,dot_diam;
|
|
dot_diam#=max(dot_size#,cap_curve#);
|
|
beginchar(oct"040",9u#,min(asc_height#,10/7x_height#+.5dot_diam#),0);
|
|
dot_diam=max(tiny.breadth,hround(max(dot_size,cap_curve)-2stem_corr));
|
|
italcorr h#*slant+.5dot_diam#-2.25u#;
|
|
adjust_fit(0,0);
|
|
pickup tiny.nib; pos1(dot_diam,0); pos2(dot_diam,90);
|
|
x1=x2=2.75u; top y2r=h+1;
|
|
if bot y2l<x_height+o+slab: y2l:=min(y2r-eps,x_height+o+slab+.5tiny); fi
|
|
y1=.5[y2l,y2r]; dot(1,2); % left dot
|
|
pos3(dot_diam,0); penpos4(y2r-y2l,90); y3=y4=y1; x3=x4=w-x1;
|
|
dot(3,4); % right dot
|
|
penlabels(1,2,3,4); endchar;
|
|
|
|
cmchar "Closing quotes";
|
|
beginchar(oct"042",7u#+max(2u#,dot_size#),asc_height#,0);
|
|
italcorr asc_height#*slant+dot_size#-4.1u#;
|
|
adjust_fit(0,0);
|
|
x1-.5dot_size=hround .6u; y2+.5dot_size=h;
|
|
x2-x1=hround(1.5u+max(2u,dot_size)); y2=y1;
|
|
comma(1,a,dot_size,.25u,comma_depth); % left dot and tail
|
|
comma(2,b,dot_size,.25u,comma_depth); % right dot and tail
|
|
penlabels(1,2); endchar;
|
|
|
|
cmchar "Cyrillic breve";
|
|
beginchar(oct"044",8u#,x_height#+1.75dot_size#,0);
|
|
italcorr h#*slant+.5vair#-1.5u#;
|
|
adjust_fit(0,0);
|
|
pickup crisp.nib; pos1(vair,-180); pos3(vair,0);
|
|
top y1=top y3=h; lft x1r=hround(.5u-.5vair); rt x3r=hround(w-.5u+.5vair);
|
|
numeric mid_thickness; mid_thickness=vround 1/3[vair,stem];
|
|
pos2(mid_thickness,-90); x2=.5w;
|
|
bot y2r=vround(x_height+.5dot_size);
|
|
filldraw stroke z1e{down}...z2e{right}...{up}z3e; % stroke
|
|
pos11(dot_size,0); pos12(dot_size,90); pos13(dot_size,0); pos14(dot_size,90);
|
|
lft x11l=lft x1r; rt x13r=rt x3r; y11=y12=y13=y14=h;
|
|
x12=x11; x14=x13; dot(11,12);
|
|
% ngb changes:
|
|
if altaccent: % relax
|
|
else: dot(13,14); fi
|
|
penlabels(1,2,3,11,13); endchar;
|
|
|
|
%cmchar "Cyrillic breve";
|
|
%beginchar(oct"044",9u#,min(asc_height#,2x_height#),0);
|
|
%italcorr h#*slant+.5vair#-1.5u#;
|
|
%adjust_fit(0,0);
|
|
%pickup crisp.nib; pos1(vair,-180); pos3(vair,0);
|
|
%top y1=top y3=h; lft x1r=hround(.5w-4u-.5vair); rt x3r=hround(.5w+4u+.5vair);
|
|
%numeric mid_thickness; mid_thickness=vround 1/3[vair,stem];
|
|
%pos2(mid_thickness,-90); x2=.5w;
|
|
%bot y2r=vround max(x_height+o+tiny,1/3[x_height,h]+o-.5mid_thickness);
|
|
%filldraw stroke z1e{down}...z2e{right}...{up}z3e; % stroke
|
|
%pos11(dot_size,0); pos12(dot_size,90); pos13(dot_size,0); pos14(dot_size,90);
|
|
%lft x11l=lft x1r; rt x13r=rt x3r; y11=y12=y13=y14=h;
|
|
%x12=x11; x14=x13; dot(11,12); dot(13,14);
|
|
%penlabels(1,2,3,11,13); endchar;
|
|
|
|
cmchar "Acute accent";
|
|
beginchar(oct"046",9u#,min(asc_height#,2x_height#),0);
|
|
italcorr h#*slant-if serifs: 1.5 fi u#;
|
|
adjust_fit(0,0);
|
|
if serifs: pickup crisp.nib; x1+.5stem=hround(w-2u); x2=2/3[x1,w-x1];
|
|
y1+.5stem=h+eps; y2=max(2/3[h,x_height],x_height+o+hair);
|
|
numeric theta; theta=angle(z2-z1)+90;
|
|
pos1(stem,theta); pos2(hair,theta);
|
|
filldraw circ_stroke z1e--z2e; % diagonal
|
|
else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
|
|
rt x1r=hround(w-1.5u); lft x2l=hround(.5w-.25u-.5vair);
|
|
top y1=h; bot y2=vround 2/3[h,x_height];
|
|
filldraw stroke z1e--z2e; fi % diagonal
|
|
penlabels(1,2); endchar;
|
|
|
|
cmchar "open cyrillic quote (looks like <<)";
|
|
beginchar(oct"074",10u#,x_height#,0);
|
|
adjust_fit(if monospace:-u#,-u# else: 0,0 fi); pickup rule.nib;
|
|
lft x2=hround u-epsilon; x1=x3=.55w;
|
|
y1=h; y3=0; y2=.5[y1,y3];
|
|
draw z1--z2--z3; % left diagonals
|
|
x4=w-x2; y4=.9[y3,y1]; y6=.1[y3,y1];
|
|
x5-x2=x6-x3=x4-x1; y5=y2;
|
|
draw z4--z5--z6; % right diagonals
|
|
z2'=z2; x2':=x2-.625rule_thickness;
|
|
z5'=z5; x5':=x5+.625rule_thickness;
|
|
draw z1--z2'--z3; % left diagonals
|
|
draw z4--z5'--z6; % right diagonals
|
|
labels(1,2,3,4,5,6); endchar;
|
|
|
|
cmchar "close cyrillic quote (looks like >>)";
|
|
beginchar(oct"076",10u#,x_height#,0);
|
|
adjust_fit(if monospace:-u#,-u# else: 0,0 fi); pickup rule.nib;
|
|
%lft x2=.55w; x1=x3=hround u-epsilon;
|
|
%y1=.9h; y3=.1h; y2=.5[y1,y3];
|
|
%y4=h; y6=0; y5=.5[y4,y6];
|
|
%draw z1--z2--z3; % left diagonals
|
|
%x4=w-x2;
|
|
%x5-x2=x6-x3=x4-x1;
|
|
%draw z4--z5--z6; % right diagonals
|
|
%z2'=z2; x2':=x2-.625rule_thickness;
|
|
%z5'=z5; x5':=x5+.625rule_thickness;
|
|
%draw z1--z2'--z3; % left diagonals
|
|
%draw z4--z5'--z6; % right diagonals
|
|
%labels(1,2,3,4,5,6);
|
|
slantswitch;
|
|
pickup rule.nib;
|
|
lft x2=hround u-epsilon; x1=x3=.55w;
|
|
y1=h; y3=0; y2=.5[y1,y3];
|
|
draw z1--z2--z3; % left diagonals
|
|
x4=w-x2; y4=.9[y3,y1]; y6=.1[y3,y1];
|
|
x5-x2=x6-x3=x4-x1; y5=y2;
|
|
draw z4--z5--z6; % right diagonals
|
|
z2'=z2; x2':=x2-.625rule_thickness;
|
|
z5'=z5; x5':=x5+.625rule_thickness;
|
|
draw z1--z2'--z3; % left diagonals
|
|
draw z4--z5'--z6; % right diagonals
|
|
mirror(.5w);
|
|
endchar;
|
|
|
|
cmchar "Breve accent";
|
|
beginchar(oct"100",9u#,min(asc_height#,2x_height#),0);
|
|
italcorr h#*slant+.5vair#-1.5u#;
|
|
adjust_fit(0,0);
|
|
pickup crisp.nib; pos1(vair,-180); pos3(vair,0);
|
|
top y1=top y3=h; lft x1r=w-rt x3r=hround(2u-.5vair);
|
|
numeric mid_thickness; mid_thickness=vround 1/3[vair,stem];
|
|
pos2(mid_thickness,-90); x2=.5w;
|
|
bot y2r=vround max(x_height+o+tiny,1/3[x_height,h]+o-.5mid_thickness);
|
|
filldraw stroke z1e{down}...z2e{right}...{up}z3e; % stroke
|
|
penlabels(1,2,3); endchar;
|
|
|
|
cmchar "Opening quotes";
|
|
beginchar(oct"134",7u#+max(2u#,dot_size#),asc_height#,0);
|
|
italcorr asc_height#*slant-.1u#;
|
|
adjust_fit(0,0);
|
|
x2+.5dot_size=hround(w-.6u); y1+.5dot_size=h-comma_depth;
|
|
x2-x1=hround(1.5u+max(2u,dot_size)); y2=y1;
|
|
ammoc(1,a,dot_size,.25u,comma_depth); % left dot and tail
|
|
ammoc(2,b,dot_size,.25u,comma_depth); % right dot and tail
|
|
penlabels(1,2); endchar;
|
|
|
|
cmchar "En dash";
|
|
beginchar(oct"173",9u#,x_height#,0);
|
|
italcorr .61803x_height#*slant+.5u#;
|
|
adjust_fit(0,0);
|
|
pickup crisp.nib; pos1(vair,90); pos2(vair,90);
|
|
top y1r=top y2r=vround(.61803h+.5vair); lft x1=-eps; rt x2=w+eps;
|
|
filldraw stroke z1e--z2e; % bar
|
|
penlabels(1,2); endchar;
|
|
|
|
cmchar "Em dash";
|
|
beginchar(oct"174",18u#,x_height#,0);
|
|
italcorr .61803x_height#*slant+.5u#;
|
|
adjust_fit(letter_fit#,letter_fit#);
|
|
pickup crisp.nib; pos1(vair,90); pos2(vair,90);
|
|
top y1r=top y2r=vround(.61803h+.5vair); lft x1=-eps; rt x2=w+eps;
|
|
filldraw stroke z1e--z2e; % bar
|
|
penlabels(1,2); endchar;
|
|
|
|
cmchar "The symbol No.";
|
|
beginchar(oct"175",15u#+width_adj#,cap_height#,0);
|
|
italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
|
|
adjust_fit(cap_serif_fit#,cap_serif_fit#); w:=if serifs: 10u else: 11u fi;
|
|
numeric thin_stem; thin_stem=hround(fudged.hair+stem_corr);
|
|
pickup tiny.nib; pos1(thin_stem,0); pos2(thin_stem,0);
|
|
pos3(thin_stem,0); pos4(thin_stem,0);
|
|
pickup tiny.nib; top y1=h;
|
|
if serifs: top y3=.79h; bot y2=.21h; else: top y3=h; bot y2=0; fi
|
|
bot y4=0;
|
|
x1=x2; x3=x4; x1l=w-x3r;
|
|
rt x3r=hround min(w-2u,w-3u+.5fudged.cap_stem);
|
|
x91=x2-.75flare; bot y91r=-oo; x92=w-x91; top y92l=h+oo;
|
|
pos91(thin_stem,-90); pos92(thin_stem,-90);
|
|
if serifs: filldraw stroke z1e--z2e & pulled_arc.e(2,91); % left stem
|
|
filldraw stroke z4e--z3e & pulled_arc.e(3,92); % right stem
|
|
else: filldraw stroke z1e--z2e; filldraw stroke z4e--z3e;
|
|
fi
|
|
if hefty: penpos5(fudged.cap_stem,0); penpos6(fudged.cap_stem,0);
|
|
x5l=x1; x6r=x4; y5=h; y6=0;
|
|
numeric upper_notch,lower_notch;
|
|
upper_notch=h-cap_notch_cut; lower_notch=cap_notch_cut;
|
|
x1'=rt x1r; z1'=whatever[z5l,z6l]; x4'=lft x4l; z4'=whatever[z5r,z6r];
|
|
fill z5l..
|
|
if y1'<upper_notch: {right}(x1'+1,upper_notch){down}... fi
|
|
{z6-z5}diag_in(5l,6l,1,6r)--z6r..
|
|
if y4'>lower_notch: {left}(x4'-1,lower_notch){up}... fi
|
|
{z5-z6}diag_in(6r,5r,1,5l)--cycle; % diagonal
|
|
else: penpos5(whatever,0); penpos6(whatever,90);
|
|
z5l=z1l; z6l=z4l;
|
|
z7=z6l+(max(eps,cap_stem-3stem_corr-tiny),0) rotated (angle(z5l-z6l)-90);
|
|
z5r=z7+whatever*(z5l-z6l); z6r=z7+whatever*(z5l-z6l);
|
|
filldraw stroke z5e..z6e; fi % diagonal
|
|
if serifs: if hefty: serif(1,2,a,1/3,-cap_jut); % upper left serif
|
|
else: serif(5,6,a,1/3,-cap_jut); fi % upper left serif
|
|
fi
|
|
pickup tiny.nib;
|
|
if serifs:
|
|
x93=x2-1.5flare; y93=.75flare; pos95(flare+(cap_stem-stem),-180);
|
|
x94=x3+1.5flare; y94=h-y93; pos96(flare+(cap_stem-stem),0);
|
|
pos92'(thin_stem,90); z92'=z92;
|
|
pos93(cap_hair,-180); pos94(cap_hair,0); bulb(91,93,95); bulb(92',94,96);
|
|
fi
|
|
w:=15u;
|
|
penpos71(vair,90); penpos73(vair',-90);
|
|
penpos72(.8curve,180); penpos74(.8curve,0);
|
|
x72r=hround max(.5u,1.25u-.4curve)+9.5u;
|
|
x74r=w-x72r+9u; x71=x73=12u; y71r=h-3u+vround 1.5oo; y73r=x_height-3u-oo;
|
|
y72=y74=.5[h,x_height]-3u-vair_corr; y72l:=y74l:=.52[h,x_height]-3u;
|
|
penstroke pulled_arc.e(71,72) & pulled_arc.e(72,73)
|
|
& pulled_arc.e(73,74) & pulled_arc.e(74,71) & cycle; % bowl
|
|
x81=lft x72r; x82=rt x74r; y81=y82=.8x_height-3u; pos81(bar,90); pos82(bar,90);
|
|
filldraw stroke z81e--z82e;
|
|
math_fit(0,max(.5ic#-.5u#,0)); penlabels(1,1',2,3,4,4',5,6,7); endchar;
|
|
|